[FFmpeg-devel,v2] aarch64/opusdsp: implement NEON accelerated postfilter and deemphasis

Submitted by Lynne on April 2, 2019, 11:47 a.m.

Details

Message ID LbSrvEo--3-1@lynne.ee
State New
Headers show

Commit Message

Lynne April 2, 2019, 11:47 a.m.
153372 UNITS in postfilter_c,   65536 runs,      0 skips
73164 UNITS in postfilter_neon,   65536 runs,      0 skips -> 2.1x speedup

80591 UNITS in deemphasis_c,  131072 runs,      0 skips
43969 UNITS in deemphasis_neon,  131072 runs,      0 skips -> 1.83x speedup

Total decoder speedup: ~15% on a Raspberry Pi 3 (from 28.1x to 33.5x realtime)

Deemphasis SIMD based on the following unrolling:
const float c1 = CELT_EMPH_COEFF, c2 = c1*c1, c3 = c2*c1, c4 = c3*c1;
float state = coeff;

for (int i = 0; i < len; i += 4) {
    y[0] = x[0] + c1*state;
    y[1] = x[1] + c2*state + c1*x[0];
    y[2] = x[2] + c3*state + c1*x[1] + c2*x[0];
    y[3] = x[3] + c4*state + c1*x[2] + c2*x[1] + c3*x[0];

    state = y[3];
    y += 4;
    x += 4;
}

Unlike the x86 version, duplication is used instead of pslldq so
the structure and tables are different.

Comments

Carl Eugen Hoyos April 6, 2019, 1:42 p.m.
2019-04-02 13:47 GMT+02:00, Lynne <dev@lynne.ee>:
> 153372 UNITS in postfilter_c,   65536 runs,      0 skips
> 73164 UNITS in postfilter_neon,   65536 runs,      0 skips -> 2.1x speedup
>
> 80591 UNITS in deemphasis_c,  131072 runs,      0 skips
> 43969 UNITS in deemphasis_neon,  131072 runs,      0 skips -> 1.83x speedup

> Total decoder speedup: ~15% on a Raspberry Pi 3 (from
> 28.1x to 33.5x realtime)

How can I reproduce this?
On something called "X-Gene" Linux, I see a 2,5% overall
speedup (126x to 129x)

The issue is that there is some probability that your patch will
break mac and Windows compilation, so I would at least
like to understand why I can not reproduce your speedup.

Carl Eugen
Lynne April 6, 2019, 2:08 p.m.
Apr 6, 2019, 2:42 PM by ceffmpeg@gmail.com:

> 2019-04-02 13:47 GMT+02:00, Lynne <> dev@lynne.ee <mailto:dev@lynne.ee>> >:
>
>> 153372 UNITS in postfilter_c,   65536 runs,      0 skips
>> 73164 UNITS in postfilter_neon,   65536 runs,      0 skips -> 2.1x speedup
>>
>> 80591 UNITS in deemphasis_c,  131072 runs,      0 skips
>> 43969 UNITS in deemphasis_neon,  131072 runs,      0 skips -> 1.83x speedup
>>
>> Total decoder speedup: ~15% on a Raspberry Pi 3 (from
>> 28.1x to 33.5x realtime)
>>
>
> How can I reproduce this?
> On something called "X-Gene" Linux, I see a 2,5% overall
> speedup (126x to 129x)
>
> The issue is that there is some probability that your patch will
> break mac and Windows compilation, so I would at least
> like to understand why I can not reproduce your speedup.
>

I tested this on real hardware.
How can this break mac support at all when it doesn't support aarch64? And I can't find a windows aarch64 compiler either.
Carl Eugen Hoyos April 6, 2019, 2:41 p.m.
2019-04-06 16:08 GMT+02:00, Lynne <dev@lynne.ee>:
>
>
>
> Apr 6, 2019, 2:42 PM by ceffmpeg@gmail.com:
>
>> 2019-04-02 13:47 GMT+02:00, Lynne <> dev@lynne.ee <mailto:dev@lynne.ee>>
>> >:
>>
>>> 153372 UNITS in postfilter_c,   65536 runs,      0 skips
>>> 73164 UNITS in postfilter_neon,   65536 runs,      0 skips -> 2.1x
>>> speedup
>>>
>>> 80591 UNITS in deemphasis_c,  131072 runs,      0 skips
>>> 43969 UNITS in deemphasis_neon,  131072 runs,      0 skips -> 1.83x
>>> speedup
>>>
>>> Total decoder speedup: ~15% on a Raspberry Pi 3 (from
>>> 28.1x to 33.5x realtime)
>>>
>>
>> How can I reproduce this?

Meaning:
Where can I find the file you used?

>> On something called "X-Gene" Linux, I see a 2,5% overall
>> speedup (126x to 129x)
>>
>> The issue is that there is some probability that your patch will
>> break mac and Windows compilation, so I would at least
>> like to understand why I can not reproduce your speedup.
>>
>
> I tested this on real hardware.

Is X-Gene not real hardware?

> How can this break mac support at all when it doesn't
> support aarch64?

Have you heard of iPhones?

> And I can't find a windows aarch64 compiler either.

There is one (I don't know more).

Carl Eugen
Lynne April 9, 2019, 1:53 p.m.
Apr 6, 2019, 3:41 PM by ceffmpeg@gmail.com:

> 2019-04-06 16:08 GMT+02:00, Lynne <> dev@lynne.ee <mailto:dev@lynne.ee>> >:
>
>>
>>
>>
>> Apr 6, 2019, 2:42 PM by >> ceffmpeg@gmail.com <mailto:ceffmpeg@gmail.com>>> :
>>
>>> 2019-04-02 13:47 GMT+02:00, Lynne <> >>> dev@lynne.ee <mailto:dev@lynne.ee>>>>  <mailto:>>> dev@lynne.ee <mailto:dev@lynne.ee>>>> >>
>>> >:
>>>
>>>> 153372 UNITS in postfilter_c,   65536 runs,      0 skips
>>>> 73164 UNITS in postfilter_neon,   65536 runs,      0 skips -> 2.1x
>>>> speedup
>>>>
>>>> 80591 UNITS in deemphasis_c,  131072 runs,      0 skips
>>>> 43969 UNITS in deemphasis_neon,  131072 runs,      0 skips -> 1.83x
>>>> speedup
>>>>
>>>> Total decoder speedup: ~15% on a Raspberry Pi 3 (from
>>>> 28.1x to 33.5x realtime)
>>>>
>>>
>>> How can I reproduce this?
>>>
>
> Meaning:
> Where can I find the file you used?
>

Sorry for the delay. Here's a test file:
http://www.mediafire.com/file/awg5lfy4j2dv85k/testfile.opus/file <http://www.mediafire.com/file/awg5lfy4j2dv85k/testfile.opus/file>



>>> On something called "X-Gene" Linux, I see a 2,5% overall
>>> speedup (126x to 129x)
>>>
>>> The issue is that there is some probability that your patch will
>>> break mac and Windows compilation, so I would at least
>>> like to understand why I can not reproduce your speedup.
>>>
>>
>> I tested this on real hardware.
>>
>
> Is X-Gene not real hardware?
>

Didn't find much about it at all. If you don't get performance improvements I think someone with a more popular board should test it.


>> How can this break mac support at all when it doesn't
>> support aarch64?
>>
>
> Have you heard of iPhones?
>

Those use iOS.


>> And I can't find a windows aarch64 compiler either.
>>
>
> There is one (I don't know more).
>

I still don't know how you can suggest this patch will break any operating systems when you haven't tested either.
Carl Eugen Hoyos April 9, 2019, 11:10 p.m.
2019-04-02 13:47 GMT+02:00, Lynne <dev@lynne.ee>:
> 153372 UNITS in postfilter_c,   65536 runs,      0 skips
> 73164 UNITS in postfilter_neon,   65536 runs,      0 skips -> 2.1x speedup
>
> 80591 UNITS in deemphasis_c,  131072 runs,      0 skips
> 43969 UNITS in deemphasis_neon,  131072 runs,      0 skips -> 1.83x speedup

> Total decoder speedup: ~15% on a Raspberry Pi 3 (from 28.1x to 33.5x
> realtime)

Reproduced 7%, tested on compilation on macos and pushed.

Carl Eugen

Patch hide | download patch | download mbox

From afcab2dbeac26ae07689c7e58d0acc94a1c1c3e3 Mon Sep 17 00:00:00 2001
From: Lynne <dev@lynne.ee>
Date: Fri, 15 Mar 2019 14:37:31 +0000
Subject: [PATCH v2] aarch64/opusdsp: implement NEON accelerated postfilter and
 deemphasis

153372 UNITS in postfilter_c,   65536 runs,      0 skips
73164 UNITS in postfilter_neon,   65536 runs,      0 skips -> 2.1x speedup

80591 UNITS in deemphasis_c,  131072 runs,      0 skips
43969 UNITS in deemphasis_neon,  131072 runs,      0 skips -> 1.83x speedup

Total decoder speedup: ~15% on a Raspberry Pi 3 (from 28.1x to 33.5x realtime)

Deemphasis SIMD based on the following unrolling:
const float c1 = CELT_EMPH_COEFF, c2 = c1*c1, c3 = c2*c1, c4 = c3*c1;
float state = coeff;

for (int i = 0; i < len; i += 4) {
    y[0] = x[0] + c1*state;
    y[1] = x[1] + c2*state + c1*x[0];
    y[2] = x[2] + c3*state + c1*x[1] + c2*x[0];
    y[3] = x[3] + c4*state + c1*x[2] + c2*x[1] + c3*x[0];

    state = y[3];
    y += 4;
    x += 4;
}

Unlike the x86 version, duplication is used instead of pslldq so
the structure and tables are different.
---
 libavcodec/aarch64/Makefile       |   2 +
 libavcodec/aarch64/opusdsp_init.c |  35 +++++++++
 libavcodec/aarch64/opusdsp_neon.S | 113 ++++++++++++++++++++++++++++++
 libavcodec/opusdsp.c              |   3 +
 libavcodec/opusdsp.h              |   1 +
 5 files changed, 154 insertions(+)
 create mode 100644 libavcodec/aarch64/opusdsp_init.c
 create mode 100644 libavcodec/aarch64/opusdsp_neon.S

diff --git a/libavcodec/aarch64/Makefile b/libavcodec/aarch64/Makefile
index 8bc8bc528c..00f93bf59f 100644
--- a/libavcodec/aarch64/Makefile
+++ b/libavcodec/aarch64/Makefile
@@ -15,6 +15,7 @@  OBJS-$(CONFIG_VP8DSP)                   += aarch64/vp8dsp_init_aarch64.o
 OBJS-$(CONFIG_AAC_DECODER)              += aarch64/aacpsdsp_init_aarch64.o \
                                            aarch64/sbrdsp_init_aarch64.o
 OBJS-$(CONFIG_DCA_DECODER)              += aarch64/synth_filter_init.o
+OBJS-$(CONFIG_OPUS_DECODER)             += aarch64/opusdsp_init.o
 OBJS-$(CONFIG_RV40_DECODER)             += aarch64/rv40dsp_init_aarch64.o
 OBJS-$(CONFIG_VC1DSP)                   += aarch64/vc1dsp_init_aarch64.o
 OBJS-$(CONFIG_VORBIS_DECODER)           += aarch64/vorbisdsp_init.o
@@ -49,6 +50,7 @@  NEON-OBJS-$(CONFIG_VP8DSP)              += aarch64/vp8dsp_neon.o
 # decoders/encoders
 NEON-OBJS-$(CONFIG_AAC_DECODER)         += aarch64/aacpsdsp_neon.o
 NEON-OBJS-$(CONFIG_DCA_DECODER)         += aarch64/synth_filter_neon.o
+NEON-OBJS-$(CONFIG_OPUS_DECODER)        += aarch64/opusdsp_neon.o
 NEON-OBJS-$(CONFIG_VORBIS_DECODER)      += aarch64/vorbisdsp_neon.o
 NEON-OBJS-$(CONFIG_VP9_DECODER)         += aarch64/vp9itxfm_16bpp_neon.o       \
                                            aarch64/vp9itxfm_neon.o             \
diff --git a/libavcodec/aarch64/opusdsp_init.c b/libavcodec/aarch64/opusdsp_init.c
new file mode 100644
index 0000000000..cc6a1b672d
--- /dev/null
+++ b/libavcodec/aarch64/opusdsp_init.c
@@ -0,0 +1,35 @@ 
+/*
+ * This file is part of FFmpeg.
+ *
+ * FFmpeg is free software; you can redistribute it and/or
+ * modify it under the terms of the GNU Lesser General Public
+ * License as published by the Free Software Foundation; either
+ * version 2.1 of the License, or (at your option) any later version.
+ *
+ * FFmpeg is distributed in the hope that it will be useful,
+ * but WITHOUT ANY WARRANTY; without even the implied warranty of
+ * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
+ * Lesser General Public License for more details.
+ *
+ * You should have received a copy of the GNU Lesser General Public
+ * License along with FFmpeg; if not, write to the Free Software
+ * Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA
+ */
+
+#include "config.h"
+
+#include "libavutil/aarch64/cpu.h"
+#include "libavcodec/opusdsp.h"
+
+void ff_opus_postfilter_neon(float *data, int period, float *gains, int len);
+float ff_opus_deemphasis_neon(float *out, float *in, float coeff, int len);
+
+av_cold void ff_opus_dsp_init_aarch64(OpusDSP *ctx)
+{
+    int cpu_flags = av_get_cpu_flags();
+
+    if (have_neon(cpu_flags)) {
+        ctx->postfilter = ff_opus_postfilter_neon;
+        ctx->deemphasis = ff_opus_deemphasis_neon;
+    }
+}
diff --git a/libavcodec/aarch64/opusdsp_neon.S b/libavcodec/aarch64/opusdsp_neon.S
new file mode 100644
index 0000000000..3d805e2c9c
--- /dev/null
+++ b/libavcodec/aarch64/opusdsp_neon.S
@@ -0,0 +1,113 @@ 
+/*
+ * This file is part of FFmpeg.
+ *
+ * FFmpeg is free software; you can redistribute it and/or
+ * modify it under the terms of the GNU Lesser General Public
+ * License as published by the Free Software Foundation; either
+ * version 2.1 of the License, or (at your option) any later version.
+ *
+ * FFmpeg is distributed in the hope that it will be useful,
+ * but WITHOUT ANY WARRANTY; without even the implied warranty of
+ * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
+ * Lesser General Public License for more details.
+ *
+ * You should have received a copy of the GNU Lesser General Public
+ * License along with FFmpeg; if not, write to the Free Software
+ * Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA
+ */
+
+#include "libavutil/aarch64/asm.S"
+
+           // 0.85..^1    0.85..^2    0.85..^3    0.85..^4
+const tab_st, align=4
+        .word 0x3f599a00, 0x3f38f671, 0x3f1d382a, 0x3f05a32f
+endconst
+const tab_x0, align=4
+        .word 0x0,        0x3f599a00, 0x3f38f671, 0x3f1d382a
+endconst
+const tab_x1, align=4
+        .word 0x0,        0x0,        0x3f599a00, 0x3f38f671
+endconst
+const tab_x2, align=4
+        .word 0x0,        0x0,        0x0,        0x3f599a00
+endconst
+
+function ff_opus_deemphasis_neon, export=1
+        movrel  x4, tab_st
+        ld1    {v4.4s}, [x4]
+        movrel  x4, tab_x0
+        ld1    {v5.4s}, [x4]
+        movrel  x4, tab_x1
+        ld1    {v6.4s}, [x4]
+        movrel  x4, tab_x2
+        ld1    {v7.4s}, [x4]
+
+        fmul v0.4s, v4.4s, v0.s[0]
+
+1:      ld1  {v1.4s, v2.4s}, [x1], #32
+
+        fmla v0.4s, v5.4s, v1.s[0]
+        fmul v3.4s, v7.4s, v2.s[2]
+
+        fmla v0.4s, v6.4s, v1.s[1]
+        fmla v3.4s, v6.4s, v2.s[1]
+
+        fmla v0.4s, v7.4s, v1.s[2]
+        fmla v3.4s, v5.4s, v2.s[0]
+
+        fadd v1.4s, v1.4s, v0.4s
+        fadd v2.4s, v2.4s, v3.4s
+
+        fmla v2.4s, v4.4s, v1.s[3]
+
+        st1  {v1.4s, v2.4s}, [x0], #32
+        fmul v0.4s, v4.4s, v2.s[3]
+
+        subs w2, w2, #8
+        b.gt 1b
+
+        mov s0, v2.s[3]
+
+        ret
+endfunc
+
+function ff_opus_postfilter_neon, export=1
+        ld1 {v0.4s}, [x2]
+        dup v1.4s, v0.s[1]
+        dup v2.4s, v0.s[2]
+        dup v0.4s, v0.s[0]
+
+        add w1, w1, #2
+        sub x1, x0, x1, lsl #2
+
+        ld1 {v3.4s}, [x1]
+        fmul v3.4s, v3.4s, v2.4s
+
+1:      add x1, x1, #4
+        ld1 {v4.4s}, [x1]
+        add x1, x1, #4
+        ld1 {v5.4s}, [x1]
+        add x1, x1, #4
+        ld1 {v6.4s}, [x1]
+        add x1, x1, #4
+        ld1 {v7.4s}, [x1]
+
+        fmla v3.4s, v7.4s, v2.4s
+        fadd v6.4s, v6.4s, v4.4s
+
+        ld1 {v8.4s}, [x0]
+        fmla v8.4s, v5.4s, v0.4s
+
+        fmul v6.4s, v6.4s, v1.4s
+        fadd v6.4s, v6.4s, v3.4s
+
+        fadd v8.4s, v8.4s, v6.4s
+        fmul v3.4s, v7.4s, v2.4s
+
+        st1  {v8.4s}, [x0], #16
+
+        subs w3, w3, #4
+        b.gt 1b
+
+        ret
+endfunc
diff --git a/libavcodec/opusdsp.c b/libavcodec/opusdsp.c
index 17e819f977..0e179c98c9 100644
--- a/libavcodec/opusdsp.c
+++ b/libavcodec/opusdsp.c
@@ -61,4 +61,7 @@  av_cold void ff_opus_dsp_init(OpusDSP *ctx)
 
     if (ARCH_X86)
         ff_opus_dsp_init_x86(ctx);
+
+    if (ARCH_AARCH64)
+        ff_opus_dsp_init_aarch64(ctx);
 }
diff --git a/libavcodec/opusdsp.h b/libavcodec/opusdsp.h
index e3eb457f1b..ee3186dd44 100644
--- a/libavcodec/opusdsp.h
+++ b/libavcodec/opusdsp.h
@@ -31,5 +31,6 @@  typedef struct OpusDSP {
 void ff_opus_dsp_init(OpusDSP *ctx);
 
 void ff_opus_dsp_init_x86(OpusDSP *ctx);
+void ff_opus_dsp_init_aarch64(OpusDSP *ctx);
 
 #endif /* AVCODEC_OPUSDSP_H */
-- 
2.20.1