diff mbox series

[FFmpeg-devel,4/5] lavc/aarch64: Add neon implementation for sse8

Message ID 20220715080228.686736-5-hum@semihalf.com
State New
Headers show
Series Add neon implementation for me_cmp functions | expand

Checks

Context Check Description
yinshiyou/make_loongarch64 success Make finished
yinshiyou/make_fate_loongarch64 success Make fate finished
andriy/make_x86 success Make finished
andriy/make_fate_x86 success Make fate finished

Commit Message

Hubert Mazur July 15, 2022, 8:02 a.m. UTC
Provide optimized implementation of sse8 function for arm64.

Performance comparison tests are shown below.
- sse_1_c: 133.0
- sse_1_neon: 36.7

Benchmarks and tests run with checkasm tool on AWS Graviton 3.

Signed-off-by: Hubert Mazur <hum@semihalf.com>
---
 libavcodec/aarch64/me_cmp_init_aarch64.c |  3 +
 libavcodec/aarch64/me_cmp_neon.S         | 72 ++++++++++++++++++++++++
 2 files changed, 75 insertions(+)
diff mbox series

Patch

diff --git a/libavcodec/aarch64/me_cmp_init_aarch64.c b/libavcodec/aarch64/me_cmp_init_aarch64.c
index 07d62cc1e5..89c817990c 100644
--- a/libavcodec/aarch64/me_cmp_init_aarch64.c
+++ b/libavcodec/aarch64/me_cmp_init_aarch64.c
@@ -34,6 +34,8 @@  int ff_pix_abs16_y2_neon(MpegEncContext *v, uint8_t *pix1, uint8_t *pix2,
 
 int sse16_neon(MpegEncContext *v, uint8_t *pix1, uint8_t *pix2,
                   ptrdiff_t stride, int h);
+int sse8_neon(MpegEncContext *v, uint8_t *pix1, uint8_t *pix2,
+                  ptrdiff_t stride, int h);
 int sse4_neon(MpegEncContext *v, uint8_t *pix1, uint8_t *pix2,
                   ptrdiff_t stride, int h);
 
@@ -49,6 +51,7 @@  av_cold void ff_me_cmp_init_aarch64(MECmpContext *c, AVCodecContext *avctx)
 
         c->sad[0] = ff_pix_abs16_neon;
         c->sse[0] = sse16_neon;
+        c->sse[1] = sse8_neon;
         c->sse[2] = sse4_neon;
     }
 }
diff --git a/libavcodec/aarch64/me_cmp_neon.S b/libavcodec/aarch64/me_cmp_neon.S
index 858833b0ae..c78e26df4b 100644
--- a/libavcodec/aarch64/me_cmp_neon.S
+++ b/libavcodec/aarch64/me_cmp_neon.S
@@ -361,6 +361,78 @@  function sse16_neon, export=1
 
 endfunc
 
+function sse8_neon, export=1
+        // x0 - unused
+        // x1 - pix1
+        // x2 - pix2
+        // x3 - stride
+        // w4 - h
+
+        movi            d18, #0
+        cmp             w4, #4
+        b.le            2f
+
+// make 4 iterations at once
+1:
+
+        // res = abs(pix1[0] - pix2[0])
+        // res * res
+
+        ld1             {v0.8b}, [x1], x3
+        ld1             {v1.8b}, [x2], x3
+        uabdl           v30.8h, v0.8b, v1.8b
+        umull           v21.4s, v30.4h, v30.4h
+        ld1             {v2.8b}, [x1], x3
+        umull2          v20.4s, v30.8h, v30.8h
+        ld1             {v3.8b}, [x2], x3
+        uabdl           v29.8h, v2.8b, v3.8b
+        ld1             {v4.8b}, [x1], x3
+        umlal           v21.4s, v29.4h, v29.4h
+        ld1             {v5.8b}, [x2], x3
+        umlal2          v20.4s, v29.8h, v29.8h
+        uabdl           v28.8h, v4.8b, v5.8b
+        ld1             {v6.8b}, [x1], x3
+        umlal           v21.4s, v28.4h, v28.4h
+        ld1             {v7.8b}, [x2], x3
+        umlal2          v20.4s, v28.8h, v28.8h
+        uabdl           v27.8h, v6.8b, v7.8b
+        umlal           v21.4s, v27.4h, v27.4h
+        umlal2          v20.4s, v27.8h, v27.8h
+
+        add             v21.4s, v21.4s, v20.4s
+        sub             w4, w4, #4
+        uaddlv          d17, v21.4s
+        add             d18, d18, d17
+        cmp             w4, #4
+        b.ge            1b
+
+        cbnz            w4, 2f
+        fmov            w0, s18
+
+        ret
+
+// iterate by one
+2:
+        ld1             {v0.8b}, [x1], x3
+        ld1             {v1.8b}, [x2], x3
+
+        uabdl           v30.8h, v0.8b, v1.8b
+        umull           v21.4s, v30.4h, v30.4h
+        umull2          v20.4s, v30.8h, v30.8h
+
+        subs            w4, w4, #1
+
+        uaddlv          d17, v21.4s
+        add             d18, d18, d17
+        uaddlv          d17, v20.4S
+        add             d18, d18, d17
+
+        b.ne            2b
+        fmov            w0, s18
+
+        ret
+endfunc
+
 function sse4_neon, export=1
         // x0 - unused
         // x1 - pix1