diff mbox series

[FFmpeg-devel] lavc/aarch64: Add neon implementation for pix_abs16_y2

Message ID 20220725111708.44992-1-hum@semihalf.com
State New
Headers show
Series [FFmpeg-devel] lavc/aarch64: Add neon implementation for pix_abs16_y2 | expand

Checks

Context Check Description
yinshiyou/configure_loongarch64 warning Failed to apply patch
andriy/configure_x86 warning Failed to apply patch

Commit Message

Hubert Mazur July 25, 2022, 11:17 a.m. UTC 
Provide optimized implementation of pix_abs16_y2 function for arm64.

Performance comparison tests are shown below.
pix_abs_0_2_c: 308.5
pix_abs_0_2_neon: 39.2

Benchmarks and tests run with checkasm tool on AWS Graviton 3.

Signed-off-by: Hubert Mazur <hum@semihalf.com>
---
 libavcodec/aarch64/me_cmp_init_aarch64.c |  3 +
 libavcodec/aarch64/me_cmp_neon.S         | 73 ++++++++++++++++++++++++
 2 files changed, 76 insertions(+)

Comments

Martin Storsjö Aug. 4, 2022, 8:08 a.m. UTC | #1 
On Mon, 25 Jul 2022, Hubert Mazur wrote:

> Provide optimized implementation of pix_abs16_y2 function for arm64.
>
> Performance comparison tests are shown below.
> pix_abs_0_2_c: 308.5
> pix_abs_0_2_neon: 39.2
>
> Benchmarks and tests run with checkasm tool on AWS Graviton 3.
>
> Signed-off-by: Hubert Mazur <hum@semihalf.com>
> ---
> libavcodec/aarch64/me_cmp_init_aarch64.c |  3 +
> libavcodec/aarch64/me_cmp_neon.S         | 73 ++++++++++++++++++++++++
> 2 files changed, 76 insertions(+)

Please do the same optimizations as done for pix_abs_xy2 in 
b46de9aba436dea0cff76f3ed0f7c98448367fd0, 
68a03f64240dcbe408c3fd43d1071a105508a588 and 
4136405c86162063e45d40d55c9985f348d4ea0a for this function too
("aarch64: me_cmp: Interleave some of the loads in ff_pix_abs16_xy2_neon", 
"aarch64: me_cmp: Switch from uabd to uabal in ff_pix_abs16_xy2_neon" and 
"aarch64: me_cmp: Don't do uaddlv once per iteration").

// Martin
Martin Storsjö Aug. 4, 2022, 8:12 a.m. UTC | #2 
On Mon, 25 Jul 2022, Hubert Mazur wrote:

> Provide optimized implementation of pix_abs16_y2 function for arm64.
>
> Performance comparison tests are shown below.
> pix_abs_0_2_c: 308.5
> pix_abs_0_2_neon: 39.2
>
> Benchmarks and tests run with checkasm tool on AWS Graviton 3.
>
> Signed-off-by: Hubert Mazur <hum@semihalf.com>
> ---
> libavcodec/aarch64/me_cmp_init_aarch64.c |  3 +
> libavcodec/aarch64/me_cmp_neon.S         | 73 ++++++++++++++++++++++++
> 2 files changed, 76 insertions(+)

> +// iterate by one
> +2:
> +
> +        ld1             {v1.16b}, [x2], x3              // Load pix2
> +        ld1             {v2.16b}, [x5], x3              // Load pix3
> +        urhadd          v30.16b, v1.16b, v2.16b         // Rounding halving add
> +        ld1             {v0.16b}, [x1], x3              // Load pix1
> +        uabd            v30.16b, v30.16b, v30.16b

This should be "uabd v30, v30, v0" here too - please check the uncommon 
codepaths too (until we can make checkasm test them by default).

// Martin
diff mbox series

Patch

diff --git a/libavcodec/aarch64/me_cmp_init_aarch64.c b/libavcodec/aarch64/me_cmp_init_aarch64.c
index 72a2062e7e..07d62cc1e5 100644
--- a/libavcodec/aarch64/me_cmp_init_aarch64.c
+++ b/libavcodec/aarch64/me_cmp_init_aarch64.c
@@ -29,6 +29,8 @@  int ff_pix_abs16_xy2_neon(MpegEncContext *s, uint8_t *blk1, uint8_t *blk2,
                       ptrdiff_t stride, int h);
 int ff_pix_abs16_x2_neon(MpegEncContext *v, uint8_t *pix1, uint8_t *pix2,
                       ptrdiff_t stride, int h);
+int ff_pix_abs16_y2_neon(MpegEncContext *v, uint8_t *pix1, uint8_t *pix2,
+                      ptrdiff_t stride, int h);
 
 int sse16_neon(MpegEncContext *v, uint8_t *pix1, uint8_t *pix2,
                   ptrdiff_t stride, int h);
@@ -42,6 +44,7 @@  av_cold void ff_me_cmp_init_aarch64(MECmpContext *c, AVCodecContext *avctx)
     if (have_neon(cpu_flags)) {
         c->pix_abs[0][0] = ff_pix_abs16_neon;
         c->pix_abs[0][1] = ff_pix_abs16_x2_neon;
+        c->pix_abs[0][2] = ff_pix_abs16_y2_neon;
         c->pix_abs[0][3] = ff_pix_abs16_xy2_neon;
 
         c->sad[0] = ff_pix_abs16_neon;
diff --git a/libavcodec/aarch64/me_cmp_neon.S b/libavcodec/aarch64/me_cmp_neon.S
index 3336d88848..6e392e9066 100644
--- a/libavcodec/aarch64/me_cmp_neon.S
+++ b/libavcodec/aarch64/me_cmp_neon.S
@@ -417,3 +417,76 @@  function sse4_neon, export=1
         ret
 
 endfunc
+
+function ff_pix_abs16_y2_neon, export=1
+        // x0           unused
+        // x1           uint8_t *pix1
+        // x2           uint8_t *pix2
+        // x3           ptrdiff_t stride
+        // x4           int h
+
+        // initialize buffers
+        movi            d18, #0
+        add             x5, x2, x3                      // pix2 + stride
+        cmp             w4, #4
+        b.lt            2f
+
+// make 4 iterations at once
+1:
+
+        // abs(pix1[0], avg2(pix2[0], pix2[0 + stride]))
+        // avg2(a, b) = (((a) + (b) + 1) >> 1)
+        // abs(x) = (x < 0 ? (-x) : (x))
+
+        ld1             {v1.16b}, [x2], x3              // Load pix2 for first iteration
+        ld1             {v2.16b}, [x5], x3              // Load pix3 for first iteration
+        urhadd          v30.16b, v1.16b, v2.16b         // Rounding halving add, first iteration
+        ld1             {v0.16b}, [x1], x3              // Load pix1 for first iteration
+        uabdl           v29.8h, v0.8b, v30.8b           // Absolute difference of lower half, first iteration
+        ld1             {v4.16b}, [x2], x3              // Load pix2 for second iteration
+        uabdl2          v28.8h, v0.16b, v30.16b         // Absolute difference of upper half, first iteration
+        ld1             {v5.16b}, [x5], x3              // Load pix3 for second iteartion
+        ld1             {v3.16b}, [x1], x3              // Load pix1 for second iteration
+        urhadd          v27.16b, v4.16b, v5.16b         // Rounding halving add, second iteration
+        uabal           v29.8h, v3.8b, v27.8b           // Absolute difference of lower half for second iteration
+        ld1             {v7.16b}, [x2], x3              // Load pix2 for third iteration
+        uabal2          v28.8h, v3.16b, v27.16b         // Absolute difference of upper half for second iteration
+        ld1             {v20.16b}, [x5], x3             // Load pix3 for third iteration
+        urhadd          v26.16b, v7.16b, v20.16b        // Rounding halving add, third iteration
+        ld1             {v6.16b}, [x1], x3              // Load pix1 for third iteration
+        uabal           v29.8h, v6.8b, v26.8b           // Absolute difference of lower half for third iteration
+        ld1             {v22.16b}, [x2], x3             // Load pix2 for fourth iteration
+        uabal2          v28.8h, v6.16b, v26.16b         // Absolute difference of upper half for third iteration
+        ld1             {v23.16b}, [x5], x3             // Load pix3 for fourth iteration
+        urhadd          v25.16b, v22.16b, v23.16b       // Rounding halving add
+        ld1             {v21.16b}, [x1], x3             // Load pix1 for fourth iteration
+        uabal           v29.8h, v21.8b, v25.8b          // Absolute difference of lower half for fourth iteration
+        uabal2          v28.8h, v21.16b, v25.16b        // Absolute difference of upper half for fourth iteration
+
+        add             v29.8h, v29.8h, v28.8h          // Add vectors together
+        sub             w4, w4, #4                      // h-= 4
+        uaddlv          s16, v29.8h                     // Add up vector values
+        cmp             w4, #4
+        add             d18, d18, d16
+        b.ge            1b
+        cbz             w4, 3f
+
+// iterate by one
+2:
+
+        ld1             {v1.16b}, [x2], x3              // Load pix2
+        ld1             {v2.16b}, [x5], x3              // Load pix3
+        urhadd          v30.16b, v1.16b, v2.16b         // Rounding halving add
+        ld1             {v0.16b}, [x1], x3              // Load pix1
+        uabd            v30.16b, v30.16b, v30.16b
+
+        uaddlv          h17, v30.16b
+        subs            w4, w4, #1
+        add             d18, d18, d17
+        b.ne            2b
+
+3:
+        fmov            w0, s18
+
+        ret
+endfunc