diff mbox series

[FFmpeg-devel] lavc/aarch64: add hevc chroma loop filter 8-12bit

Message ID 20220623105247.19580-1-jdek@itanimul.li
State New
Headers show
Series [FFmpeg-devel] lavc/aarch64: add hevc chroma loop filter 8-12bit | expand

Checks

Context Check Description
yinshiyou/make_fate_loongarch64 success Make fate finished
yinshiyou/make_loongarch64 warning New warnings during build
andriy/make_x86 success Make finished
andriy/make_fate_x86 success Make fate finished
andriy/make_armv7_RPi4 success Make finished
andriy/make_fate_armv7_RPi4 fail Make fate failed

Commit Message

J. Dekker June 23, 2022, 10:52 a.m. UTC
Signed-off-by: J. Dekker <jdek@itanimul.li>
---
 libavcodec/aarch64/Makefile               |   3 +-
 libavcodec/aarch64/hevcdsp_deblock_neon.S | 168 ++++++++++++++++++++++
 libavcodec/aarch64/hevcdsp_init_aarch64.c |  14 ++
 3 files changed, 184 insertions(+), 1 deletion(-)
 create mode 100644 libavcodec/aarch64/hevcdsp_deblock_neon.S

 Passes FATE, I never completed the checkasm for loop_filter, working on
 that currently alongside the luma loop filter. This asm can also go
 into hevcdsp_sao_neon.S if you would prefer not creating an extra file
 for it.

Comments

J. Dekker June 23, 2022, 11:44 a.m. UTC | #1
On 23 Jun 2022, at 12:52, J. Dekker wrote:

> Signed-off-by: J. Dekker <jdek@itanimul.li>
> ---
>  libavcodec/aarch64/Makefile               |   3 +-
>  libavcodec/aarch64/hevcdsp_deblock_neon.S | 168 ++++++++++++++++++++++
>  libavcodec/aarch64/hevcdsp_init_aarch64.c |  14 ++
>  3 files changed, 184 insertions(+), 1 deletion(-)
>  create mode 100644 libavcodec/aarch64/hevcdsp_deblock_neon.S
>
>  Passes FATE, I never completed the checkasm for loop_filter, working on
>  that currently alongside the luma loop filter. This asm can also go
>  into hevcdsp_sao_neon.S if you would prefer not creating an extra file
>  for it.
>
> diff --git a/libavcodec/aarch64/Makefile b/libavcodec/aarch64/Makefile
> index c8935f205e..66bd8b596c 100644
> --- a/libavcodec/aarch64/Makefile
> +++ b/libavcodec/aarch64/Makefile
> @@ -63,6 +63,7 @@ NEON-OBJS-$(CONFIG_VP9_DECODER)         += aarch64/vp9itxfm_16bpp_neon.o       \
>                                             aarch64/vp9lpf_neon.o               \
>                                             aarch64/vp9mc_16bpp_neon.o          \
>                                             aarch64/vp9mc_neon.o
> -NEON-OBJS-$(CONFIG_HEVC_DECODER)        += aarch64/hevcdsp_idct_neon.o         \
> +NEON-OBJS-$(CONFIG_HEVC_DECODER)        += aarch64/hevcdsp_deblock_neon.o      \
> +                                           aarch64/hevcdsp_idct_neon.o         \
>                                             aarch64/hevcdsp_init_aarch64.o      \
>                                             aarch64/hevcdsp_sao_neon.o
> diff --git a/libavcodec/aarch64/hevcdsp_deblock_neon.S b/libavcodec/aarch64/hevcdsp_deblock_neon.S
> new file mode 100644
> index 0000000000..d21ad0a54f
> --- /dev/null
> +++ b/libavcodec/aarch64/hevcdsp_deblock_neon.S
> @@ -0,0 +1,168 @@
> +/* -*-arm64-*-
> + * vim: syntax=arm64asm
> + *
> + * Copyright (c) 2014 Seppo Tomperi <seppo.tomperi@vtt.fi>
> + * Copyright (c) 2022 J. Dekker <jdek@itanimul.li>
> + *
> + * This file is part of FFmpeg.
> + *
> + * FFmpeg is free software; you can redistribute it and/or
> + * modify it under the terms of the GNU Lesser General Public
> + * License as published by the Free Software Foundation; either
> + * version 2.1 of the License, or (at your option) any later version.
> + *
> + * FFmpeg is distributed in the hope that it will be useful,
> + * but WITHOUT ANY WARRANTY; without even the implied warranty of
> + * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
> + * Lesser General Public License for more details.
> + *
> + * You should have received a copy of the GNU Lesser General Public
> + * License along with FFmpeg; if not, write to the Free Software
> + * Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA
> + */
> +
> +
> +#include "libavutil/aarch64/asm.S"
> +#include "neon.S"
> +
> +.macro hevc_loop_filter_chroma_start bitdepth
> +        ldr             w14, [x2]
> +        ldr             w15, [x2, #4]
> +.if \bitdepth > 8
> +        lsl             w14, w14, #(\bitdepth - 8)
> +        lsl             w15, w15, #(\bitdepth - 8)
> +.endif
> +        adds            w2, w14, w15
> +        b.eq            1f
> +        dup             v16.4h, w14
> +        dup             v17.4h, w15
> +        trn1            v16.2d, v16.2d, v17.2d
> +.if \bitdepth == 10
> +        mvni            v19.8h, #0xFC, lsl #8 // movi #0x03FF
> +.endif
> +.if \bitdepth == 12
> +        mvni            v19.8h, #0xF0, lsl #8 // movi #0x0FFF
> +.endif
> +.if \bitdepth > 8
> +        movi            v18.8h, #0
> +.endif
> +        neg             v17.8h, v16.8h
> +.endm
> +
> +.macro hevc_loop_filter_chroma_body bitdepth
> +.if \bitdepth <= 8
> +        uxtl            v0.8h, v0.8b // p1
> +        uxtl            v1.8h, v1.8b // p0
> +        uxtl            v2.8h, v2.8b // q0
> +        uxtl            v3.8h, v3.8b // q1
> +.endif
> +        sub             v5.8h, v2.8h, v1.8h // q0 - p0
> +        sub             v6.8h, v0.8h, v3.8h // p1 - q1
> +        shl             v5.8h, v5.8h, #2
> +        add             v5.8h, v6.8h, v5.8h
> +        srshr           v5.8h, v5.8h, #3
> +        smin            v5.8h, v5.8h, v16.8h
> +        smax            v5.8h, v5.8h, v17.8h
> +        sqadd           v1.8h, v1.8h, v5.8h // p0 + delta
> +        sqsub           v2.8h, v2.8h, v5.8h // q0 - delta
> +.if \bitdepth <= 8
> +        sqxtun          v1.8b, v1.8h
> +        sqxtun          v2.8b, v2.8h
> +.else
> +        smin            v1.8h, v1.8h, v19.8h
> +        smin            v2.8h, v2.8h, v19.8h
> +        smax            v1.8h, v1.8h, v18.8h
> +        smax            v2.8h, v2.8h, v18.8h
> +.endif
> +.endm
> +
> +.macro hevc_h_loop_filter_chroma bitdepth
> +function ff_hevc_h_loop_filter_chroma_\bitdepth\()_neon, export=1
> +        hevc_loop_filter_chroma_start \bitdepth
> +        sub             x0, x0, x1, lsl #1
> +.if \bitdepth > 8
> +        ld1             {v0.8h}, [x0], x1
> +        ld1             {v1.8h}, [x0], x1
> +        ld1             {v2.8h}, [x0], x1
> +        ld1             {v3.8h}, [x0]
> +.else
> +        ld1             {v0.8b}, [x0], x1
> +        ld1             {v1.8b}, [x0], x1
> +        ld1             {v2.8b}, [x0], x1
> +        ld1             {v3.8h}, [x0]
> +.endif
> +        hevc_loop_filter_chroma_body \bitdepth
> +        sub             x0, x0, x1, lsl #1
> +.if \bitdepth > 8
> +        st1             {v1.8h}, [x0], x1
> +        st1             {v2.8h}, [x0]
> +.else
> +        st1             {v1.8b}, [x0], x1
> +        st1             {v2.8b}, [x0]
> +.endif
> +1:      ret
> +endfunc
> +.endm
> +
> +.macro hevc_v_loop_filter_chroma bitdepth
> +function ff_hevc_v_loop_filter_chroma_\bitdepth\()_neon, export=1
> +        hevc_loop_filter_chroma_start \bitdepth
> +.if \bitdepth > 8
> +        sub             x0, x0, #8
> +        ld1             {v20.8h}, [x0], x1
> +        ld1             {v21.8h}, [x0], x1
> +        ld1             {v0.8h},  [x0], x1
> +        ld1             {v1.8h},  [x0], x1
> +        ld1             {v2.8h},  [x0], x1
> +        ld1             {v3.8h},  [x0], x1
> +        ld1             {v22.8h}, [x0], x1
> +        ld1             {v23.8h}, [x0], x1
> +        transpose_8x8H  v20, v21, v0, v1, v2, v3, v22, v23, v24, v25
> +.else
> +        sub             x0, x0, #4
> +        ld1             {v20.8b}, [x0], x1
> +        ld1             {v21.8b}, [x0], x1
> +        ld1             {v0.8b},  [x0], x1
> +        ld1             {v1.8b},  [x0], x1
> +        ld1             {v2.8b},  [x0], x1
> +        ld1             {v3.8b},  [x0], x1
> +        ld1             {v22.8b}, [x0], x1
> +        ld1             {v23.8b}, [x0], x1
> +        transpose_8x8B  v20, v21, v0, v1, v2, v3, v22, v23, v24, v25
> +.endif
> +        hevc_loop_filter_chroma_body \bitdepth
> +        sub             x0, x0, x1, lsl #3
> +.if \bitdepth > 8
> +        transpose_8x8H  v20, v21, v0, v1, v2, v3, v22, v23, v24, v25
> +        st1             {v20.8h}, [x0], x1
> +        st1             {v21.8h}, [x0], x1
> +        st1             {v0.8h},  [x0], x1
> +        st1             {v1.8h},  [x0], x1
> +        st1             {v2.8h},  [x0], x1
> +        st1             {v3.8h},  [x0], x1
> +        st1             {v22.8h}, [x0], x1
> +        st1             {v23.8h}, [x0]
> +.else
> +        xtn             v0.8b, v0.8h // restore
> +        xtn             v3.8b, v3.8h
> +        transpose_8x8B  v20, v21, v0, v1, v2, v3, v22, v23, v24, v25
> +        st1             {v20.8b}, [x0], x1
> +        st1             {v21.8b}, [x0], x1
> +        st1             {v0.8b},  [x0], x1
> +        st1             {v1.8b},  [x0], x1
> +        st1             {v2.8b},  [x0], x1
> +        st1             {v3.8b},  [x0], x1
> +        st1             {v22.8b}, [x0], x1
> +        st1             {v23.8b}, [x0]
> +.endif
> +1:      ret
> +endfunc
> +.endm
> +
> +hevc_h_loop_filter_chroma 8
> +hevc_h_loop_filter_chroma 10
> +hevc_h_loop_filter_chroma 12
> +
> +hevc_v_loop_filter_chroma 8
> +hevc_v_loop_filter_chroma 10
> +hevc_v_loop_filter_chroma 12
> diff --git a/libavcodec/aarch64/hevcdsp_init_aarch64.c b/libavcodec/aarch64/hevcdsp_init_aarch64.c
> index 2002530266..3502edb77a 100644
> --- a/libavcodec/aarch64/hevcdsp_init_aarch64.c
> +++ b/libavcodec/aarch64/hevcdsp_init_aarch64.c
> @@ -25,6 +25,12 @@
>  #include "libavutil/aarch64/cpu.h"
>  #include "libavcodec/hevcdsp.h"
>
> +void ff_hevc_v_loop_filter_chroma_8_neon(uint8_t *_pix, ptrdiff_t _stride, int *_tc, uint8_t *_no_p, uint8_t *_no_q);
> +void ff_hevc_v_loop_filter_chroma_10_neon(uint8_t *_pix, ptrdiff_t _stride, int *_tc, uint8_t *_no_p, uint8_t *_no_q);
> +void ff_hevc_v_loop_filter_chroma_12_neon(uint8_t *_pix, ptrdiff_t _stride, int *_tc, uint8_t *_no_p, uint8_t *_no_q);
> +void ff_hevc_h_loop_filter_chroma_8_neon(uint8_t *_pix, ptrdiff_t _stride, int *_tc, uint8_t *_no_p, uint8_t *_no_q);
> +void ff_hevc_h_loop_filter_chroma_10_neon(uint8_t *_pix, ptrdiff_t _stride, int *_tc, uint8_t *_no_p, uint8_t *_no_q);
> +void ff_hevc_h_loop_filter_chroma_12_neon(uint8_t *_pix, ptrdiff_t _stride, int *_tc, uint8_t *_no_p, uint8_t *_no_q);
>  void ff_hevc_add_residual_4x4_8_neon(uint8_t *_dst, int16_t *coeffs,
>                                       ptrdiff_t stride);
>  void ff_hevc_add_residual_4x4_10_neon(uint8_t *_dst, int16_t *coeffs,
> @@ -67,6 +73,8 @@ av_cold void ff_hevc_dsp_init_aarch64(HEVCDSPContext *c, const int bit_depth)
>      if (!have_neon(av_get_cpu_flags())) return;
>
>      if (bit_depth == 8) {
> +        c->hevc_h_loop_filter_chroma   = ff_hevc_h_loop_filter_chroma_8_neon;
> +        c->hevc_v_loop_filter_chroma   = ff_hevc_v_loop_filter_chroma_8_neon;
>          c->add_residual[0]             = ff_hevc_add_residual_4x4_8_neon;
>          c->add_residual[1]             = ff_hevc_add_residual_8x8_8_neon;
>          c->add_residual[2]             = ff_hevc_add_residual_16x16_8_neon;
> @@ -89,6 +97,8 @@ av_cold void ff_hevc_dsp_init_aarch64(HEVCDSPContext *c, const int bit_depth)
>          c->sao_edge_filter[4]          = ff_hevc_sao_edge_filter_16x16_8_neon;
>      }
>      if (bit_depth == 10) {
> +        c->hevc_h_loop_filter_chroma   = ff_hevc_h_loop_filter_chroma_10_neon;
> +        c->hevc_v_loop_filter_chroma   = ff_hevc_v_loop_filter_chroma_10_neon;
>          c->add_residual[0]             = ff_hevc_add_residual_4x4_10_neon;
>          c->add_residual[1]             = ff_hevc_add_residual_8x8_10_neon;
>          c->add_residual[2]             = ff_hevc_add_residual_16x16_10_neon;
> @@ -100,4 +110,8 @@ av_cold void ff_hevc_dsp_init_aarch64(HEVCDSPContext *c, const int bit_depth)
>          c->idct_dc[2]                  = ff_hevc_idct_16x16_dc_10_neon;
>          c->idct_dc[3]                  = ff_hevc_idct_32x32_dc_10_neon;
>      }
> +    if (bit_depth == 12) {
> +        c->hevc_h_loop_filter_chroma   = ff_hevc_h_loop_filter_chroma_12_neon;
> +        c->hevc_v_loop_filter_chroma   = ff_hevc_v_loop_filter_chroma_12_neon;
> +    }
>  }

Self-review for this patch since I just thought of some things I could change: Stores/loads can be interleaved in both filters and for the vertical filter maybe I don't need to write the full 8b/8h. Other than that maybe some slightly scheduling improvements?
diff mbox series

Patch

diff --git a/libavcodec/aarch64/Makefile b/libavcodec/aarch64/Makefile
index c8935f205e..66bd8b596c 100644
--- a/libavcodec/aarch64/Makefile
+++ b/libavcodec/aarch64/Makefile
@@ -63,6 +63,7 @@  NEON-OBJS-$(CONFIG_VP9_DECODER)         += aarch64/vp9itxfm_16bpp_neon.o       \
                                            aarch64/vp9lpf_neon.o               \
                                            aarch64/vp9mc_16bpp_neon.o          \
                                            aarch64/vp9mc_neon.o
-NEON-OBJS-$(CONFIG_HEVC_DECODER)        += aarch64/hevcdsp_idct_neon.o         \
+NEON-OBJS-$(CONFIG_HEVC_DECODER)        += aarch64/hevcdsp_deblock_neon.o      \
+                                           aarch64/hevcdsp_idct_neon.o         \
                                            aarch64/hevcdsp_init_aarch64.o      \
                                            aarch64/hevcdsp_sao_neon.o
diff --git a/libavcodec/aarch64/hevcdsp_deblock_neon.S b/libavcodec/aarch64/hevcdsp_deblock_neon.S
new file mode 100644
index 0000000000..d21ad0a54f
--- /dev/null
+++ b/libavcodec/aarch64/hevcdsp_deblock_neon.S
@@ -0,0 +1,168 @@ 
+/* -*-arm64-*-
+ * vim: syntax=arm64asm
+ *
+ * Copyright (c) 2014 Seppo Tomperi <seppo.tomperi@vtt.fi>
+ * Copyright (c) 2022 J. Dekker <jdek@itanimul.li>
+ *
+ * This file is part of FFmpeg.
+ *
+ * FFmpeg is free software; you can redistribute it and/or
+ * modify it under the terms of the GNU Lesser General Public
+ * License as published by the Free Software Foundation; either
+ * version 2.1 of the License, or (at your option) any later version.
+ *
+ * FFmpeg is distributed in the hope that it will be useful,
+ * but WITHOUT ANY WARRANTY; without even the implied warranty of
+ * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
+ * Lesser General Public License for more details.
+ *
+ * You should have received a copy of the GNU Lesser General Public
+ * License along with FFmpeg; if not, write to the Free Software
+ * Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA
+ */
+
+
+#include "libavutil/aarch64/asm.S"
+#include "neon.S"
+
+.macro hevc_loop_filter_chroma_start bitdepth
+        ldr             w14, [x2]
+        ldr             w15, [x2, #4]
+.if \bitdepth > 8
+        lsl             w14, w14, #(\bitdepth - 8)
+        lsl             w15, w15, #(\bitdepth - 8)
+.endif
+        adds            w2, w14, w15
+        b.eq            1f
+        dup             v16.4h, w14
+        dup             v17.4h, w15
+        trn1            v16.2d, v16.2d, v17.2d
+.if \bitdepth == 10
+        mvni            v19.8h, #0xFC, lsl #8 // movi #0x03FF
+.endif
+.if \bitdepth == 12
+        mvni            v19.8h, #0xF0, lsl #8 // movi #0x0FFF
+.endif
+.if \bitdepth > 8
+        movi            v18.8h, #0
+.endif
+        neg             v17.8h, v16.8h
+.endm
+
+.macro hevc_loop_filter_chroma_body bitdepth
+.if \bitdepth <= 8
+        uxtl            v0.8h, v0.8b // p1
+        uxtl            v1.8h, v1.8b // p0
+        uxtl            v2.8h, v2.8b // q0
+        uxtl            v3.8h, v3.8b // q1
+.endif
+        sub             v5.8h, v2.8h, v1.8h // q0 - p0
+        sub             v6.8h, v0.8h, v3.8h // p1 - q1
+        shl             v5.8h, v5.8h, #2
+        add             v5.8h, v6.8h, v5.8h
+        srshr           v5.8h, v5.8h, #3
+        smin            v5.8h, v5.8h, v16.8h
+        smax            v5.8h, v5.8h, v17.8h
+        sqadd           v1.8h, v1.8h, v5.8h // p0 + delta
+        sqsub           v2.8h, v2.8h, v5.8h // q0 - delta
+.if \bitdepth <= 8
+        sqxtun          v1.8b, v1.8h
+        sqxtun          v2.8b, v2.8h
+.else
+        smin            v1.8h, v1.8h, v19.8h
+        smin            v2.8h, v2.8h, v19.8h
+        smax            v1.8h, v1.8h, v18.8h
+        smax            v2.8h, v2.8h, v18.8h
+.endif
+.endm
+
+.macro hevc_h_loop_filter_chroma bitdepth
+function ff_hevc_h_loop_filter_chroma_\bitdepth\()_neon, export=1
+        hevc_loop_filter_chroma_start \bitdepth
+        sub             x0, x0, x1, lsl #1
+.if \bitdepth > 8
+        ld1             {v0.8h}, [x0], x1
+        ld1             {v1.8h}, [x0], x1
+        ld1             {v2.8h}, [x0], x1
+        ld1             {v3.8h}, [x0]
+.else
+        ld1             {v0.8b}, [x0], x1
+        ld1             {v1.8b}, [x0], x1
+        ld1             {v2.8b}, [x0], x1
+        ld1             {v3.8h}, [x0]
+.endif
+        hevc_loop_filter_chroma_body \bitdepth
+        sub             x0, x0, x1, lsl #1
+.if \bitdepth > 8
+        st1             {v1.8h}, [x0], x1
+        st1             {v2.8h}, [x0]
+.else
+        st1             {v1.8b}, [x0], x1
+        st1             {v2.8b}, [x0]
+.endif
+1:      ret
+endfunc
+.endm
+
+.macro hevc_v_loop_filter_chroma bitdepth
+function ff_hevc_v_loop_filter_chroma_\bitdepth\()_neon, export=1
+        hevc_loop_filter_chroma_start \bitdepth
+.if \bitdepth > 8
+        sub             x0, x0, #8
+        ld1             {v20.8h}, [x0], x1
+        ld1             {v21.8h}, [x0], x1
+        ld1             {v0.8h},  [x0], x1
+        ld1             {v1.8h},  [x0], x1
+        ld1             {v2.8h},  [x0], x1
+        ld1             {v3.8h},  [x0], x1
+        ld1             {v22.8h}, [x0], x1
+        ld1             {v23.8h}, [x0], x1
+        transpose_8x8H  v20, v21, v0, v1, v2, v3, v22, v23, v24, v25
+.else
+        sub             x0, x0, #4
+        ld1             {v20.8b}, [x0], x1
+        ld1             {v21.8b}, [x0], x1
+        ld1             {v0.8b},  [x0], x1
+        ld1             {v1.8b},  [x0], x1
+        ld1             {v2.8b},  [x0], x1
+        ld1             {v3.8b},  [x0], x1
+        ld1             {v22.8b}, [x0], x1
+        ld1             {v23.8b}, [x0], x1
+        transpose_8x8B  v20, v21, v0, v1, v2, v3, v22, v23, v24, v25
+.endif
+        hevc_loop_filter_chroma_body \bitdepth
+        sub             x0, x0, x1, lsl #3
+.if \bitdepth > 8
+        transpose_8x8H  v20, v21, v0, v1, v2, v3, v22, v23, v24, v25
+        st1             {v20.8h}, [x0], x1
+        st1             {v21.8h}, [x0], x1
+        st1             {v0.8h},  [x0], x1
+        st1             {v1.8h},  [x0], x1
+        st1             {v2.8h},  [x0], x1
+        st1             {v3.8h},  [x0], x1
+        st1             {v22.8h}, [x0], x1
+        st1             {v23.8h}, [x0]
+.else
+        xtn             v0.8b, v0.8h // restore
+        xtn             v3.8b, v3.8h
+        transpose_8x8B  v20, v21, v0, v1, v2, v3, v22, v23, v24, v25
+        st1             {v20.8b}, [x0], x1
+        st1             {v21.8b}, [x0], x1
+        st1             {v0.8b},  [x0], x1
+        st1             {v1.8b},  [x0], x1
+        st1             {v2.8b},  [x0], x1
+        st1             {v3.8b},  [x0], x1
+        st1             {v22.8b}, [x0], x1
+        st1             {v23.8b}, [x0]
+.endif
+1:      ret
+endfunc
+.endm
+
+hevc_h_loop_filter_chroma 8
+hevc_h_loop_filter_chroma 10
+hevc_h_loop_filter_chroma 12
+
+hevc_v_loop_filter_chroma 8
+hevc_v_loop_filter_chroma 10
+hevc_v_loop_filter_chroma 12
diff --git a/libavcodec/aarch64/hevcdsp_init_aarch64.c b/libavcodec/aarch64/hevcdsp_init_aarch64.c
index 2002530266..3502edb77a 100644
--- a/libavcodec/aarch64/hevcdsp_init_aarch64.c
+++ b/libavcodec/aarch64/hevcdsp_init_aarch64.c
@@ -25,6 +25,12 @@ 
 #include "libavutil/aarch64/cpu.h"
 #include "libavcodec/hevcdsp.h"
 
+void ff_hevc_v_loop_filter_chroma_8_neon(uint8_t *_pix, ptrdiff_t _stride, int *_tc, uint8_t *_no_p, uint8_t *_no_q);
+void ff_hevc_v_loop_filter_chroma_10_neon(uint8_t *_pix, ptrdiff_t _stride, int *_tc, uint8_t *_no_p, uint8_t *_no_q);
+void ff_hevc_v_loop_filter_chroma_12_neon(uint8_t *_pix, ptrdiff_t _stride, int *_tc, uint8_t *_no_p, uint8_t *_no_q);
+void ff_hevc_h_loop_filter_chroma_8_neon(uint8_t *_pix, ptrdiff_t _stride, int *_tc, uint8_t *_no_p, uint8_t *_no_q);
+void ff_hevc_h_loop_filter_chroma_10_neon(uint8_t *_pix, ptrdiff_t _stride, int *_tc, uint8_t *_no_p, uint8_t *_no_q);
+void ff_hevc_h_loop_filter_chroma_12_neon(uint8_t *_pix, ptrdiff_t _stride, int *_tc, uint8_t *_no_p, uint8_t *_no_q);
 void ff_hevc_add_residual_4x4_8_neon(uint8_t *_dst, int16_t *coeffs,
                                      ptrdiff_t stride);
 void ff_hevc_add_residual_4x4_10_neon(uint8_t *_dst, int16_t *coeffs,
@@ -67,6 +73,8 @@  av_cold void ff_hevc_dsp_init_aarch64(HEVCDSPContext *c, const int bit_depth)
     if (!have_neon(av_get_cpu_flags())) return;
 
     if (bit_depth == 8) {
+        c->hevc_h_loop_filter_chroma   = ff_hevc_h_loop_filter_chroma_8_neon;
+        c->hevc_v_loop_filter_chroma   = ff_hevc_v_loop_filter_chroma_8_neon;
         c->add_residual[0]             = ff_hevc_add_residual_4x4_8_neon;
         c->add_residual[1]             = ff_hevc_add_residual_8x8_8_neon;
         c->add_residual[2]             = ff_hevc_add_residual_16x16_8_neon;
@@ -89,6 +97,8 @@  av_cold void ff_hevc_dsp_init_aarch64(HEVCDSPContext *c, const int bit_depth)
         c->sao_edge_filter[4]          = ff_hevc_sao_edge_filter_16x16_8_neon;
     }
     if (bit_depth == 10) {
+        c->hevc_h_loop_filter_chroma   = ff_hevc_h_loop_filter_chroma_10_neon;
+        c->hevc_v_loop_filter_chroma   = ff_hevc_v_loop_filter_chroma_10_neon;
         c->add_residual[0]             = ff_hevc_add_residual_4x4_10_neon;
         c->add_residual[1]             = ff_hevc_add_residual_8x8_10_neon;
         c->add_residual[2]             = ff_hevc_add_residual_16x16_10_neon;
@@ -100,4 +110,8 @@  av_cold void ff_hevc_dsp_init_aarch64(HEVCDSPContext *c, const int bit_depth)
         c->idct_dc[2]                  = ff_hevc_idct_16x16_dc_10_neon;
         c->idct_dc[3]                  = ff_hevc_idct_32x32_dc_10_neon;
     }
+    if (bit_depth == 12) {
+        c->hevc_h_loop_filter_chroma   = ff_hevc_h_loop_filter_chroma_12_neon;
+        c->hevc_v_loop_filter_chroma   = ff_hevc_v_loop_filter_chroma_12_neon;
+    }
 }